Грамматика языка

Согласно индивидуальному варианту задания на курсовую работу (вариант №1), грамматика языка включает следующие синтаксические конструкции:

1. <операции\_группы\_отношения> ::= <> | = | < | <= | > | >=

2. <операции\_группы\_сложения> ::= + | - | or

3. <операции\_группы\_умножения> ::= \* | / | and

4. <унарная\_операция> ::= not

5. <программа> ::= program var <описание> begin <оператор> {;<оператор>} end

6. <описание> ::= {<идентификатор> {, <идентификатор> } : <тип>;}

7. <тип> ::= % | ! | $

8. <оператор>::= <составной> | <присваивания> | <условный> | <фиксированного\_цикла> | <условного\_цикла> | <ввода> | <вывода>

9. <составной>::= «[» <оператор> { ( : | перевод строки) <оператор> } «]»

10. <присваивания>::= <идентификатор> as <выражение>

11. <условный>::= if <выражение> then <оператор> [ else <оператор>]

12. <фиксированного\_цикла>::= for <присваивания> to <выражение> do <оператор>

13. <условного\_цикла>::= while <выражение> do <оператор>

14. <ввода>::= read «(»<идентификатор> {, <идентификатор> } «)»

15. <вывода>::= write «(»<выражение> {, <выражение> } «)»

16. <выражение> ::= <операнд> {<операции\_группы\_отношения> <операнд>}

17. <операнд> ::= <слагаемое> {<операции\_группы\_сложения> <слагаемое>}

18. <слагаемое> ::= <множитель> {<операции\_группы\_умножения> <множитель>}

19. <множитель> ::= <идентификатор> | <число> | <логическая\_константа> | <унарная\_операция> <множитель> | «(» <выражение> «)»

20. <логическая\_константа> ::= true | false

21. <идентификатор>::= <буква> {<буква> | <цифра>}

22. <число>::= <целое> | <действительное>

23. <целое>::= <двоичное> | <восьмеричное> | <десятичное> | <шестнадцатеричное>

24. <двоичное>::= {/ 0 | 1 /} (B | b)

25. <восьмеричное>::= {/ 0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 /} (O | o)

26. <десятичное>::= {/ <цифра> /} [D | d]

27. <шестнадцатеричное>::= <цифра> {<цифра> | A | B | C | D | E | F | a | b | c | d | e | f} (H | h)

28 <действительное>::= <числовая\_строка> <порядок> |[<числовая\_строка>] . <числовая\_строка> [порядок]

29. <числовая\_строка>::= {/ <цифра> /}

30. <порядок>::= ( E | e )[+ | -] <числовая\_строка>

31. <буква> ::= a | b | c | d | e | f | g | h | i | j | k | l | m | n | o | p | q | r | s | t | u | v

| w | x | y | z | A | B | C | D | E | F | G | H | I | J | K | L | M | N | O | P | Q | R | S | T | U |

V | W | X | Y | Z

32. <цифра> ::= 0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | 9

\*для записи правил грамматики используется форма Бэкуса-Наура(БНФ). В записи БНФ левая и правая части порождения разделяются символом «::=», нетерминалы заключены в угловые скобки, а терминалы – просто символы, используемые в языке.

<программа> 𝑃 → 𝒑𝒓𝒐𝒈𝒓𝒂𝒎 𝐷1; 𝐵 ⊥

<описание> 𝐷1 → 𝒗𝒂𝒓 𝐷 {, 𝐷}

𝐷 → 𝐼 {, 𝐼}: **[% | ! | $**]

<оператор> 𝐵 → 𝒃𝒆𝒈𝒊𝒏 𝑆 {; 𝑆} 𝒆𝒏𝒅

𝑆 → So | Pr | U | Fc | Uc| Re | Wr

<составной> So → “[“S {( **:** | \n) S}”]”

<присваивания> Pr → I **as** E

<условный> U → **if** E **then** S [**else** S]

<фиксированного\_цикла> Fc → **for** Pr **to** E **do** S

<условного\_цикла> Uc → **while** E **do** S

<ввода> Re → **read**”(“I{,I}”)”

<вывода> Wr → **write**”(“E{,E}”)”

<выражение> 𝐸 → 𝐸1{[<> | = | < | <= | > | >=]𝐸1}

<операнд> 𝐸1 → 𝑇{[ + | − | 𝒐𝒓 ] 𝑇}

<слагаемое> 𝑇 → 𝐹{[ ∗ | / | 𝒂𝒏𝒅 ] 𝐹}

<множитель> 𝐹 → 𝐼 | 𝑁 | 𝐿| 𝒏𝒐𝒕 𝐹 | (𝐸)

<идентификатор> 𝐼 → C {C | R}

<число> N → N1 | N2

<целое> N1 → Nd | Ne | Nt | Ns

<двоичное> Nd → {/ 0 | 1 /} (‘B’ | ‘b’)

<восьмеричное> Ne→ {/ 0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 /} (‘O’ | ‘o’)

<десятичное> Nt → {/ R /} [‘D’ | ‘d’]

<шестнадцатеричное>Ns → R {R | C} (‘H’ | ‘h’)

<действительное> N2 → Rs Po | [Rs] . Rs [Po]

<числовая\_строка> Rs → {/ R /}

<порядок> Po → ( E | e )[+ | -] Rs

<буква>C → a | b | c | d | e | f | g | h | i | j | k | l | m | n | o | p | q | r | s | t | u | v

| w | x | y | z | A | B | C | D | E | F | G | H | I | J | K | L | M | N | O | P | Q | R | S | T | U |

V | W | X | Y | Z

<цифра>R → 0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | 9

<логическая\_константа>L → **true** | **false**